# vim: set tabstop=2 expandtab syntax=sed:

# General stuff.

# Kill trailing whitespace.
/^-- $/!s/ \{1,\}$//

# Some people do sigdashes improperly.
s/^--$/-- /
s/^=====$/-- /

# wipe secondary gpg user ids
/^gpg:[ ]\+aka/d
/^gpg:[ ]\+There is no indication that the signature belongs to the owner\.$/d
/^Primary key fingerprint:/d


###
# Destroy various mailing list and other footers.

# Generic Yahoo Groups
/^\(> \)*-\{24\} Yahoo! Groups Sponsor -\{20,21\}~-->$/,/^\(> \)*-\{69\}~->$/d
/^Your use of Yahoo! Groups is subject to /d

# generic mailman
/^_\{47\}$/,/^http:\/\/.*\/mailman\/listinfo/d

# Sourceforge
/^-\{55\}$/,/^https:\/\/lists\.sourceforge.net\/lists\/listinfo/d

# Debian
/^To UNSUBSCRIBE, email to debian/,+1d
#/^-- \?$/,/^mit dem Subject/d

# Yahoo ads.
#/^_\{34\}$/,/^http:\/\/sitebuilder\.yahoo\.com$/d
#/^-\{33\}$/,/Yahoo! Health - Feel better, live better$/d
#/^_\{64\}$/,/visit www\.juno\.com to sign up today!$/d
/^-\{50\}$/,/yahoo\.com/d

/^\[Non-text portions of this message have been removed\]/,+28d
/^To unsubscribe from the list just send a blank message to: Exmormon-unsubscribe/,+28d

# Hotmail ads.
/^_\{65\}$/,/^http:\/\/www\.hotmail\.com$/d

# Lycos ads.
/^_\{53\}$/,/^http:\/\/www\.mail\.lycos\.com\/brandPage\.shtml\?pageId=plus$/d
/^_\{60\}$/,/http:\/\/www\.mail\.lycos\.com\/brandPage\.shtml\?pageId=plus$/d